| Flutter iOS Embedder |

FlutterDartProject.mm
Go to the documentation of this file.
1 // Copyright 2013 The Flutter Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style license that can be
3 // found in the LICENSE file.
4
5 #define FML_USED_ON_EMBEDDER
6
7 #import "flutter/shell/platform/darwin/ios/framework/Source/FlutterDartProject_Internal.h"
8
9 #include <syslog.h>
10
11 #import <Metal/Metal.h>
12 #include <sstream>
13 #include <string>
14
15 #include "flutter/common/constants.h"
16 #include "flutter/common/task_runners.h"
17 #include "flutter/fml/mapping.h"
18 #include "flutter/fml/message_loop.h"
19 #include "flutter/fml/platform/darwin/scoped_nsobject.h"
20 #include "flutter/runtime/dart_vm.h"
21 #include "flutter/shell/common/shell.h"
22 #include "flutter/shell/common/switches.h"
23 #import "flutter/shell/platform/darwin/common/command_line.h"
24 #import "flutter/shell/platform/darwin/ios/framework/Headers/FlutterViewController.h"
25
26 FLUTTER_ASSERT_NOT_ARC
27
28 extern "C" {
29 #if FLUTTER_RUNTIME_MODE == FLUTTER_RUNTIME_MODE_DEBUG
30 // Used for debugging dart:* sources.
31 extern const uint8_t kPlatformStrongDill[];
32 extern const intptr_t kPlatformStrongDillSize;
33 #endif
34 }
35
36 static const char* kApplicationKernelSnapshotFileName = "kernel_blob.bin";
37
38 static BOOL DoesHardwareSupportWideGamut() {
39 static BOOL result = NO;
40 static dispatch_once_t once_token = 0;
41 dispatch_once(&once_token, ^{
42 id<MTLDevice> device = MTLCreateSystemDefaultDevice();
43 if (@available(iOS 13.0, *)) {
44 // MTLGPUFamilyApple2 = A9/A10
45 result = [device supportsFamily:MTLGPUFamilyApple2];
46 } else {
47 // A9/A10 on iOS 10+
48 result = [device supportsFeatureSet:MTLFeatureSet_iOS_GPUFamily3_v2];
49 }
50 [device release];
51 });
52 return result;
53 }
54
55 flutter::Settings FLTDefaultSettingsForBundle(NSBundle* bundle, NSProcessInfo* processInfoOrNil) {
56 auto command_line = flutter::CommandLineFromNSProcessInfo(processInfoOrNil);
57
58 // Precedence:
59 // 1. Settings from the specified NSBundle (except for enable-impeller).
60 // 2. Settings passed explicitly via command-line arguments.
61 // 3. Settings from the NSBundle with the default bundle ID.
62 // 4. Settings from the main NSBundle and default values.
63
64 NSBundle* mainBundle = FLTGetApplicationBundle();
65 NSBundle* engineBundle = [NSBundle bundleForClass:[FlutterViewController class]];
66
67 bool hasExplicitBundle = bundle != nil;
68 if (bundle == nil) {
69 bundle = FLTFrameworkBundleWithIdentifier([FlutterDartProject defaultBundleIdentifier]);
70 }
71
72 auto settings = flutter::SettingsFromCommandLine(command_line);
73
74 settings.task_observer_add = [](intptr_t key, const fml::closure& callback) {
75 fml::MessageLoop::GetCurrent().AddTaskObserver(key, callback);
76 };
77
78 settings.task_observer_remove = [](intptr_t key) {
79 fml::MessageLoop::GetCurrent().RemoveTaskObserver(key);
80 };
81
82 settings.log_message_callback = [](const std::string& tag, const std::string& message) {
83 // TODO(cbracken): replace this with os_log-based approach.
84 // https://github.com/flutter/flutter/issues/44030
85 std::stringstream stream;
86 if (!tag.empty()) {
87 stream << tag << ": ";
88 }
89 stream << message;
90 std::string log = stream.str();
91 syslog(LOG_ALERT, "%.*s", (int)log.size(), log.c_str());
92 };
93
94 // The command line arguments may not always be complete. If they aren't, attempt to fill in
95 // defaults.
96
97 // Flutter ships the ICU data file in the bundle of the engine. Look for it there.
98 if (settings.icu_data_path.empty()) {
99 NSString* icuDataPath = [engineBundle pathForResource:@"icudtl" ofType:@"dat"];
100 if (icuDataPath.length > 0) {
101 settings.icu_data_path = icuDataPath.UTF8String;
102 }
103 }
104
105 if (flutter::DartVM::IsRunningPrecompiledCode()) {
106 if (hasExplicitBundle) {
107 NSString* executablePath = bundle.executablePath;
108 if ([[NSFileManager defaultManager] fileExistsAtPath:executablePath]) {
109 settings.application_library_path.push_back(executablePath.UTF8String);
110 }
111 }
112
113 // No application bundle specified. Try a known location from the main bundle's Info.plist.
114 if (settings.application_library_path.empty()) {
115 NSString* libraryName = [mainBundle objectForInfoDictionaryKey:@"FLTLibraryPath"];
116 NSString* libraryPath = [mainBundle pathForResource:libraryName ofType:@""];
117 if (libraryPath.length > 0) {
118 NSString* executablePath = [NSBundle bundleWithPath:libraryPath].executablePath;
119 if (executablePath.length > 0) {
120 settings.application_library_path.push_back(executablePath.UTF8String);
121 }
122 }
123 }
124
125 // In case the application bundle is still not specified, look for the App.framework in the
126 // Frameworks directory.
127 if (settings.application_library_path.empty()) {
128 NSString* applicationFrameworkPath = [mainBundle pathForResource:@"Frameworks/App.framework"
129 ofType:@""];
130 if (applicationFrameworkPath.length > 0) {
131 NSString* executablePath =
132 [NSBundle bundleWithPath:applicationFrameworkPath].executablePath;
133 if (executablePath.length > 0) {
134 settings.application_library_path.push_back(executablePath.UTF8String);
135 }
136 }
137 }
138 }
139
140 // Checks to see if the flutter assets directory is already present.
141 if (settings.assets_path.empty()) {
142 NSString* assetsPath = FLTAssetsPathFromBundle(bundle);
143
144 if (assetsPath.length == 0) {
145 NSLog(@"Failed to find assets path for \"%@\"", bundle);
146 } else {
147 settings.assets_path = assetsPath.UTF8String;
148
149 // Check if there is an application kernel snapshot in the assets directory we could
150 // potentially use. Looking for the snapshot makes sense only if we have a VM that can use
151 // it.
152 if (!flutter::DartVM::IsRunningPrecompiledCode()) {
153 NSURL* applicationKernelSnapshotURL =
154 [NSURL URLWithString:@(kApplicationKernelSnapshotFileName)
155 relativeToURL:[NSURL fileURLWithPath:assetsPath]];
156 NSError* error;
157 if ([applicationKernelSnapshotURL checkResourceIsReachableAndReturnError:&error]) {
158 settings.application_kernel_asset = applicationKernelSnapshotURL.path.UTF8String;
159 } else {
160 NSLog(@"Failed to find snapshot at %@: %@", applicationKernelSnapshotURL.path, error);
161 }
162 }
163 }
164 }
165
166 // Domain network configuration
167 // Disabled in https://github.com/flutter/flutter/issues/72723.
168 // Re-enable in https://github.com/flutter/flutter/issues/54448.
169 settings.may_insecurely_connect_to_all_domains = true;
170 settings.domain_network_policy = "";
171
172 // Whether to enable wide gamut colors.
173 #if TARGET_OS_SIMULATOR
174 // As of Xcode 14.1, the wide gamut surface pixel formats are not supported by
175 // the simulator.
176 settings.enable_wide_gamut = false;
177 // Removes unused function warning.
178 (void)DoesHardwareSupportWideGamut;
179 #else
180 NSNumber* nsEnableWideGamut = [mainBundle objectForInfoDictionaryKey:@"FLTEnableWideGamut"];
181 BOOL enableWideGamut =
182 (nsEnableWideGamut ? nsEnableWideGamut.boolValue : YES) && DoesHardwareSupportWideGamut();
183 settings.enable_wide_gamut = enableWideGamut;
184 #endif
185
186 // TODO(dnfield): We should reverse the order for all these settings so that command line options
187 // are preferred to plist settings. https://github.com/flutter/flutter/issues/124049
188 // Whether to enable Impeller. If the command line explicitly
189 // specified an option for this, ignore what's in the plist.
190 if (!command_line.HasOption("enable-impeller")) {
191 // Next, look in the app bundle.
192 NSNumber* enableImpeller = [bundle objectForInfoDictionaryKey:@"FLTEnableImpeller"];
193 if (enableImpeller == nil) {
194 // If it isn't in the app bundle, look in the main bundle.
195 enableImpeller = [mainBundle objectForInfoDictionaryKey:@"FLTEnableImpeller"];
196 }
197 // Change the default only if the option is present.
198 if (enableImpeller != nil) {
199 settings.enable_impeller = enableImpeller.boolValue;
200 }
201 }
202
203 NSNumber* enableTraceSystrace = [mainBundle objectForInfoDictionaryKey:@"FLTTraceSystrace"];
204 // Change the default only if the option is present.
205 if (enableTraceSystrace != nil) {
206 settings.trace_systrace = enableTraceSystrace.boolValue;
207 }
208
209 NSNumber* enableDartProfiling = [mainBundle objectForInfoDictionaryKey:@"FLTEnableDartProfiling"];
210 // Change the default only if the option is present.
211 if (enableDartProfiling != nil) {
212 settings.enable_dart_profiling = enableDartProfiling.boolValue;
213 }
214
215 // Leak Dart VM settings, set whether leave or clean up the VM after the last shell shuts down.
216 NSNumber* leakDartVM = [mainBundle objectForInfoDictionaryKey:@"FLTLeakDartVM"];
217 // It will change the default leak_vm value in settings only if the key exists.
218 if (leakDartVM != nil) {
219 settings.leak_vm = leakDartVM.boolValue;
220 }
221
222 #if FLUTTER_RUNTIME_MODE == FLUTTER_RUNTIME_MODE_DEBUG
223 // There are no ownership concerns here as all mappings are owned by the
224 // embedder and not the engine.
225 auto make_mapping_callback = [](const uint8_t* mapping, size_t size) {
226 return [mapping, size]() { return std::make_unique<fml::NonOwnedMapping>(mapping, size); };
227 };
228
229 settings.dart_library_sources_kernel =
230 make_mapping_callback(kPlatformStrongDill, kPlatformStrongDillSize);
231 #endif // FLUTTER_RUNTIME_MODE == FLUTTER_RUNTIME_MODE_DEBUG
232
233 // If we even support setting this e.g. from the command line or the plist,
234 // we should let the user override it.
235 // Otherwise, we want to set this to a value that will avoid having the OS
236 // kill us. On most iOS devices, that happens somewhere near half
237 // the available memory.
238 // The VM expects this value to be in megabytes.
239 if (settings.old_gen_heap_size <= 0) {
240 settings.old_gen_heap_size = std::round([NSProcessInfo processInfo].physicalMemory * .48 /
241 flutter::kMegaByteSizeInBytes);
242 }
243
244 // This is the formula Android uses.
245 // https://android.googlesource.com/platform/frameworks/base/+/39ae5bac216757bc201490f4c7b8c0f63006c6cd/libs/hwui/renderthread/CacheManager.cpp#45
246 CGFloat scale = [UIScreen mainScreen].scale;
247 CGFloat screenWidth = [UIScreen mainScreen].bounds.size.width * scale;
248 CGFloat screenHeight = [UIScreen mainScreen].bounds.size.height * scale;
249 settings.resource_cache_max_bytes_threshold = screenWidth * screenHeight * 12 * 4;
250
251 // Whether to enable ios embedder api.
252 NSNumber* enable_embedder_api =
253 [mainBundle objectForInfoDictionaryKey:@"FLTEnableIOSEmbedderAPI"];
254 // Change the default only if the option is present.
255 if (enable_embedder_api) {
256 settings.enable_embedder_api = enable_embedder_api.boolValue;
257 }
258
259 return settings;
260 }
261
262 @implementation FlutterDartProject {
263 flutter::Settings _settings;
264 }
265
266 // This property is marked unavailable on iOS in the common header.
267 // That doesn't seem to be enough to prevent this property from being synthesized.
268 // Mark dynamic to avoid warnings.
269 @dynamic dartEntrypointArguments;
270
271 #pragma mark - Override base class designated initializers
272
273 - (instancetype)init {
274 return [self initWithPrecompiledDartBundle:nil];
275 }
276
277 #pragma mark - Designated initializers
278
279 - (instancetype)initWithPrecompiledDartBundle:(nullable NSBundle*)bundle {
280 self = [super init];
281
282 if (self) {
283 _settings = FLTDefaultSettingsForBundle(bundle);
284 }
285
286 return self;
287 }
288
289 - (instancetype)initWithSettings:(const flutter::Settings&)settings {
290 self = [self initWithPrecompiledDartBundle:nil];
291
292 if (self) {
293 _settings = settings;
294 }
295
296 return self;
297 }
298
299 #pragma mark - PlatformData accessors
300
301 - (const flutter::PlatformData)defaultPlatformData {
302 flutter::PlatformData PlatformData;
303 PlatformData.lifecycle_state = std::string("AppLifecycleState.detached");
304 return PlatformData;
305 }
306
307 #pragma mark - Settings accessors
308
309 - (const flutter::Settings&)settings {
310 return _settings;
311 }
312
313 - (flutter::RunConfiguration)runConfiguration {
314 return [self runConfigurationForEntrypoint:nil];
315 }
316
317 - (flutter::RunConfiguration)runConfigurationForEntrypoint:(nullable NSString*)entrypointOrNil {
318 return [self runConfigurationForEntrypoint:entrypointOrNil libraryOrNil:nil];
319 }
320
321 - (flutter::RunConfiguration)runConfigurationForEntrypoint:(nullable NSString*)entrypointOrNil
322 libraryOrNil:(nullable NSString*)dartLibraryOrNil {
323 return [self runConfigurationForEntrypoint:entrypointOrNil
324 libraryOrNil:dartLibraryOrNil
325 entrypointArgs:nil];
326 }
327
328 - (flutter::RunConfiguration)runConfigurationForEntrypoint:(nullable NSString*)entrypointOrNil
329 libraryOrNil:(nullable NSString*)dartLibraryOrNil
330 entrypointArgs:
331 (nullable NSArray<NSString*>*)entrypointArgs {
332 auto config = flutter::RunConfiguration::InferFromSettings(_settings);
333 if (dartLibraryOrNil && entrypointOrNil) {
334 config.SetEntrypointAndLibrary(std::string([entrypointOrNil UTF8String]),
335 std::string([dartLibraryOrNil UTF8String]));
336
337 } else if (entrypointOrNil) {
338 config.SetEntrypoint(std::string([entrypointOrNil UTF8String]));
339 }
340
341 if (entrypointArgs.count) {
342 std::vector<std::string> cppEntrypointArgs;
343 for (NSString* arg in entrypointArgs) {
344 cppEntrypointArgs.push_back(std::string([arg UTF8String]));
345 }
346 config.SetEntrypointArgs(std::move(cppEntrypointArgs));
347 }
348
349 return config;
350 }
351
352 #pragma mark - Assets-related utilities
353
354 + (NSString*)flutterAssetsName:(NSBundle*)bundle {
355 if (bundle == nil) {
356 bundle = FLTFrameworkBundleWithIdentifier([FlutterDartProject defaultBundleIdentifier]);
357 }
358 return FLTAssetPath(bundle);
359 }
360
361 + (NSString*)domainNetworkPolicy:(NSDictionary*)appTransportSecurity {
362 // https://developer.apple.com/documentation/bundleresources/information_property_list/nsapptransportsecurity/nsexceptiondomains
363 NSDictionary* exceptionDomains = [appTransportSecurity objectForKey:@"NSExceptionDomains"];
364 if (exceptionDomains == nil) {
365 return @"";
366 }
367 NSMutableArray* networkConfigArray = [[[NSMutableArray alloc] init] autorelease];
368 for (NSString* domain in exceptionDomains) {
369 NSDictionary* domainConfiguration = [exceptionDomains objectForKey:domain];
370 // Default value is false.
371 bool includesSubDomains =
372 [[domainConfiguration objectForKey:@"NSIncludesSubdomains"] boolValue];
373 bool allowsCleartextCommunication =
374 [[domainConfiguration objectForKey:@"NSExceptionAllowsInsecureHTTPLoads"] boolValue];
375 [networkConfigArray addObject:@[
376 domain, includesSubDomains ? @YES : @NO, allowsCleartextCommunication ? @YES : @NO
377 ]];
378 }
379 NSData* jsonData = [NSJSONSerialization dataWithJSONObject:networkConfigArray
380 options:0
381 error:NULL];
382 return [[[NSString alloc] initWithData:jsonData encoding:NSUTF8StringEncoding] autorelease];
383 }
384
385 + (bool)allowsArbitraryLoads:(NSDictionary*)appTransportSecurity {
386 return [[appTransportSecurity objectForKey:@"NSAllowsArbitraryLoads"] boolValue];
387 }
388
389 + (NSString*)lookupKeyForAsset:(NSString*)asset {
390 return [self lookupKeyForAsset:asset fromBundle:nil];
391 }
392
393 + (NSString*)lookupKeyForAsset:(NSString*)asset fromBundle:(nullable NSBundle*)bundle {
394 NSString* flutterAssetsName = [FlutterDartProject flutterAssetsName:bundle];
395 return [NSString stringWithFormat:@"%@/%@", flutterAssetsName, asset];
396 }
397
398 + (NSString*)lookupKeyForAsset:(NSString*)asset fromPackage:(NSString*)package {
399 return [self lookupKeyForAsset:asset fromPackage:package fromBundle:nil];
400 }
401
402 + (NSString*)lookupKeyForAsset:(NSString*)asset
403 fromPackage:(NSString*)package
404 fromBundle:(nullable NSBundle*)bundle {
405 return [self lookupKeyForAsset:[NSString stringWithFormat:@"packages/%@/%@", package, asset]
406 fromBundle:bundle];
407 }
408
409 + (NSString*)defaultBundleIdentifier {
410 return @"io.flutter.flutter.app";
411 }
412
413 - (BOOL)isWideGamutEnabled {
414 return _settings.enable_wide_gamut;
415 }
416
417 - (BOOL)isImpellerEnabled {
418 return _settings.enable_impeller;
419 }
420
421 @end
+[FlutterDartProject lookupKeyForAsset:fromPackage:fromBundle:]
NSString * lookupKeyForAsset:fromPackage:fromBundle:(NSString *asset,[fromPackage] NSString *package,[fromBundle] nullable NSBundle *bundle)
Definition: FlutterDartProject.mm:402
kApplicationKernelSnapshotFileName
static const char * kApplicationKernelSnapshotFileName
Definition: FlutterDartProject.mm:36
FlutterViewController
Definition: FlutterViewController.h:56
kPlatformStrongDillSize
const intptr_t kPlatformStrongDillSize
command_line.h
FLUTTER_ASSERT_NOT_ARC
#define FLUTTER_ASSERT_NOT_ARC
Definition: FlutterMacros.h:45
DoesHardwareSupportWideGamut
static BOOL DoesHardwareSupportWideGamut()
Definition: FlutterDartProject.mm:38
FLTAssetPath
NSString * FLTAssetPath(NSBundle *bundle)
Definition: FlutterNSBundleUtils.mm:57
FLTGetApplicationBundle
NSBundle * FLTGetApplicationBundle()
Definition: FlutterNSBundleUtils.mm:32
flutter
Definition: accessibility_bridge.h:28
flutter::CommandLineFromNSProcessInfo
fml::CommandLine CommandLineFromNSProcessInfo(NSProcessInfo *processInfoOrNil=nil)
Definition: command_line.mm:11
FLTFrameworkBundleWithIdentifier
NSBundle * FLTFrameworkBundleWithIdentifier(NSString *flutterFrameworkBundleID)
Definition: FlutterNSBundleUtils.mm:43
FlutterDartProject_Internal.h
+[FlutterDartProject flutterAssetsName:]
NSString * flutterAssetsName:(NSBundle *bundle)
FLTDefaultSettingsForBundle
flutter::Settings FLTDefaultSettingsForBundle(NSBundle *bundle, NSProcessInfo *processInfoOrNil)
Definition: FlutterDartProject.mm:55
FLTAssetsPathFromBundle
NSString * FLTAssetsPathFromBundle(NSBundle *bundle)
Definition: FlutterNSBundleUtils.mm:61
FlutterDartProject
Definition: FlutterDartProject.mm:262
+[FlutterDartProject lookupKeyForAsset:fromBundle:]
NSString * lookupKeyForAsset:fromBundle:(NSString *asset,[fromBundle] nullable NSBundle *bundle)
Definition: FlutterDartProject.mm:393
kPlatformStrongDill
const FLUTTER_ASSERT_NOT_ARC uint8_t kPlatformStrongDill[]
FlutterViewController.h